*save_checkpoint

*text_image chap_5.png center Chapter Five
*temp ontopares false
*temp morpheuschat false
*temp fumble false
*temp aresnaked false
*temp queennightmare 1
*temp succeeded false


Before you get the chance to do anything else, wings beat the air.

Morpheus, off to sulk Fates know where.

Sighing, you turn your attention to the gate

Nights off are rare for you. You can't remember the last time there wasn't a royal to torment or a hero to forewarn.

*page_break What To Do?

You could return to the acropolis, pore over Ares's invitation some more before you craft an appropriate response. Something just as thoughtful as what he sent you. Or perhaps something bolder.

There's no rush, however. The new moon is a while away, and Iris is already gone.

Instead, you could steal into the mortal realm, let Theron know his message has been delivered. And if you're drawn to him beyond his fears, perhaps this would be a good opportunity to learn about his hopes, too.

There's also Morpheus. You might wish to discuss his little feud with Hermes further. And toy with him uninterrupted by Council business while you're at it. Few things are more satisfying than wiping the smugness of his @{(Morpheus > 50) undeniably handsome face|face}. If you hurry, you should have no trouble catching up to him.

What do you do?

*choice
    #I rush home to reply to Ares.
        *set leaningtowards 1
        *set Ares %+10
        You take to the sky, turning his words over in your mind. They are, first and foremost, friendly words. Sweet and earnest. 
        
        But is there something else going on between the lines? Something more? Or is venturing so nothing more than wishful thinking on your part?

        Either way, it was kind of Ares to send a gift, especially one that smells so obscenely delicious. 
        
        Then again, it doesn't surprise you. He's always been kind @{(ruthless < 50) and you've always been in awe of him for it. He's a god of war. To hold on to that softness despite the harshness of his duties is admirable, and a far greater show of strength than dominating a battlefield ever could be|to a fault. You should feel disgusted by such a display of weakness. He is a god of war, for Fates' sake. But all you feel is warmth spreading across your chest}.
        *goto home
    #Replying can wait; I sneak a visit to Theron.
        *set leaningtowards 2
        *set Theron %+10
        You slip through the gate, for once welcoming the damp scent of the cave on the other side. Beyond its rocky mouth, your Epiali @{(epiali) slither|bounce|glide|stalk|crawl} across the bruising sky. You follow after them, reaching Leukas while the sun still lingers above the horizon.

        You approach the island via the harbor, flying close to the sea so as not to be spotted.

        This is an unsanctioned visit, after all.

        One that could land you in trouble, if Hermes were to catch wind of it.
        *goto theron1
    #Replying can wait; I follow after Morpheus.
        *set leaningtowards 3
        *set Morpheus %+10
        *set morpheuschat true
        You take to the sky, looking for a grey blur and finding nothing but violet haze.
        
        Then you catch a flicker of movement below.
        
        There. At the foot of the mist-shrouded Erebus Mountains.
        
        Morpheus, wading into a lake.
        *goto morpheus1

*label home
*page_break Fly Home

The acropolis glitters like a black diamond, jagged as the hill from which it juts out. The nymphs @{(hobby) are still|you left in the baths have gathered|are still|are still} in the courtyard, joined by a lively crowd.
 
Ox meat roasts over an open fire. Barrels of nectar have been rolled out to help wash it down. Averna is playing the lute, and a few sirens with night orchids in their hair are singing a haunting tune.

*if leaningtowards = 1
    You might join them later. Right now, there's only one thing on your mind; the scroll pressing against your hip.

    Smiling, you slip into your chambers through the balcony, grateful to find them empty.
    *goto ares1
*else
    It's your night off; you might as well join them. 
    
    By the time you stumble into your chambers, you're full of meat and merriment and orchids have been braided into your hair.

    You toss Ares's scroll and the cake on your desk. You figure it's as good a time as any to jot down a quick response. You settle into your desk and get to work.
    
    You must accept his invitation, of course. To decline could
    
    *fake_choice
        #Reflect badly on my parents.
            *set parents %+10
        #Make the Underworld look weak.
            *set ruthless %+10
        #Insult my friend.
            *set Ares %+10
            *set aresfriends true
        #Rob me of a powerful ally.
            *set cunning %+10
        #Rob me of a potential husband.
            *set diplomacy %+10
        *if wentwithares
            #Rob me of hanging out with baby drakons.
                *set daemonhandling %+10
    
    You scribble a reply and leave it for one of your Epiali to bring to Iris once they return from Hellas.
    
    Stretching, you eye the bed you seldom use for sleep. It seems to beckon you forth, and you surprise yourself by crawling into it. 
    
    Sleep comes easy, like @{(morpheuschat) sinking under the surface of a lake|watching the sun sink into the sea}.

    @{(morpheuschat) Like sweet oblivion might|Like just enjoying the view}.
    *goto main19

*label theron1
*page_break

It's just as well.
        
Theron is in the shipyard, bidding farewell to the few workers milling about their stations.

What do you do to avoid their notice?

*fake_choice
    #I cling to the hull of the closest ship.
        *set shipyard 1
        *set fitness %+10
        You climb up the side of a a half-built trireme. 
        
        Wedged between the ram and the hull, gripping the wood, you hold your position and listen.
    #I hide behind a stack of timber.
        *set shipyard 2
        *set stealth %+10
        @{(flightstyle) Wings drawn|Shadows drawn|Light on your feet}, you creep up to a pile of timber, secured with tightly woven rope.

        You can glimpse a slice of Theron's back through a narrow gap between the planks, but not much else.
    #I dive into the Halfrealm.
        *set shipyard 3
        *set cunning %+10
        One moment, you're surrounded by the sunlit shipyard. 

        The next, it's coated in a grey sheen.

        Ensconced in its shadows, you creep close to where they're standing.

"Get out of here, folks," @{(shipyard) you hear Theron tell|you hear him tell|Theron tells} the workers, "Gods know you've earned a rest."

They do as he tells them without complaint. 

A few shake their heads, some even call for him to join them. But their efforts are half-hearted, as though they're used to him staying behind, and know better than to attempt to convince him otherwise.

You can still @{(shipyard) hear them grumbling in the distance|hear them grumbling in the distance|make them out in the faded harbor} when Theron speaks into the silence.

"If you've come to kill me, you had better get it over with. I could use a rest." 

Even his warning are polite.

Then @{(shipyard) he's right beneath the ram you're clinging to|he turns around, levelling his eyes at the gap between the timber planks|he levels his eyes at the corner where you're hiding}, as though he can sense your presence.

You climb out of @{(shipyard) your hiding spot|your hiding spot|the Halfrealm} and appear before him with @{(flightstyle) a gentle swoop of your wings|a flicker of shadow|an artful leap}.

*fake_choice
    #"Are you always this nice to would-be assassins?"
        *set charm %+10
    #"If I wanted to kill you, you'd be dead already."
        *set ruthless %+10
    #"Hold your horses, mortal, I'm just here to talk."
        *set diplomacy %+10

"Hello, Goddess." He crosses his arms, a smile dangling from his lips. "Forgive me. I was certain it was a foe lurking in the shadows."

You can smell the shipyard on him, cedarwood and sweat. See it, too. Tar streaks his chitoniskos, and sawdust clings to his hands, staining them white.

"Is that a common occurrence?"

He rubs at the small scar at the base of his neck, leaving behind specks of dust. "Common enough, I suppose."

You lean against @{(shipyard) the ship|the timber planks|a stack of timber}. "And who, pray tell, wants you dead so bad?"

"Oh, plenty of folk. Political rivals. The heroes I'm currently hosting. Anybody who has heard me sing." He winks at you before adding, "I'm told it makes a harpy's wailing sound like siren song."

*fake_choice
    #I laugh heartily.
    #I shake my head.
    #I roll my eyes.

"These heroes, the ones you spoke of during our last encounter. Why did they come?"

"Let me show you," he says, leading you to a nearby ship shed. 

You recognize the vessel hauled onto it. You've seen it countless times in the Halfrealm, plaguing his dreams.

"They needed extensive repairs to their ship." He taps the hull. Sunlight glints off the freshly greased wood, catching on the eyes painted beneath the ram. "Which, as of this morning, have been completed."

What, other than you, will haunt his dreams now, you wonder.

"They'll be on their way soon, then," you say.

His brow furrows. The lines are deep, the kind that will leave a mark. "Gods' willing."

That reminds you. 

"I delivered your message to Hermes and should have some answers soon."

@{(cautiousrequest) You study his reaction, looking for any signs of deception or trickery|They deserve more than that, of course, but it's a start}.

He grows serious, fixing his eyes on yours. "Thank you, Goddess."

The relief in his voice @{(cautiousrequest) seems genuine|tugs at your chest}.

"Was there anything else?" he adds.

The question lingers between you.

[i]Is there[/i] anything else?

*choice
    #Yes. First and foremost, I came here to see him.
        "What if there were?" you venture.

        *if demure < 40
            *set maverickgoddess %+10
            *set Theron %+10            
            A bold move on your part. Dallying with a mortal almost always ends in tragedy.

            But you're drawn to him regardless.
            *goto theronmoment
        *else 
            *set Theron %+10
            *set fumble true
            But your cheeks burn as soon as the words leave your lips.

            It feels foolish to admit it. Perhaps because, deep down, you know dallying with a mortal almost always ends in tragedy.

            "I meant to say, what else could there possibly be."
            *goto theronmoment
    #There can't be, even if I want there to be.
        He is mortal. You are not.

        Dallying with him would almost certainly end in tragedy.

        *if dutiful < 40
            *set parents %+10
            *set worship %+10
            *set Theron %-5
            *set lefttheron true
            So you won't.

            "That is all," you lie.
            
            "I see." His brow furrows anew, but he doesn't dispute you. "I will ensure the proper rites are observed in your honor."

            "And I shall leave you to your work," you manage.

            His eyes threaten to pin you to the spot. It takes all your willpower to drag yourself away from them. 
            
            Once you launch into the sky, you don't allow yourself to look back.
            *goto home
        *else
            *set parents %-10
            *set maverickgoddess %+10
            *set Theron %+10
            True as all that may be, you can't resist the urge to rebel against it. To hope for things to be different–and risk it all on that hope.

            Whether it makes you selfish or brave is up to the Fates to decide.

            "What if there were?" you chance.
            *goto theronmoment
    #No. I came here only to deliver an update.
        *set Theron %-15
        *set worship %+10
        *set lefttheron true
        "That is all," you tell him politely. 

        He nods and smiles. A small smile, one that doesn't make his eyes crinkle at the edges. "I will ensure the proper rites are observed in your honor."

        "Very well." You @{(flightstyle) spread your wings|summon your shadows|kick the stone floor} "I shall leave you to your hosting."

        With that, you launch into the sky and don't look back.
        *goto home

*label theronmoment

His throat bobs, drawing your attention to the scar on his neck. He's close enough for you to make out its exact shade–silvery pink with faded purple edges.

@{(fumble) "Perhaps you should stay and find out."|"Then you could stay."}

@{(fumble) "Find out what?"|"And do what?"}

He glances at the sea and smiles. 

"What I always do, after I've packed up for the day."

*page_break Why Not?

Shortly after, you're sitting between two slipways, watching the sun dip behind the horizon. Drenching everything–the waves, the shipyard, Theron–gold.

You can't remember the last time you witnessed a sunset.

"You watch the sunset every day?"

Theron nods. "Every day I come down here."

He's still glistening from the water he splashed all over himself before he sat down.

"That's better," he'd said after scrubbing his hands and face clean. He'd ran his fingers though his curls and patted at the stray drops dripping down his neck and forearms with a cloth.

@{(demure < 50) Quite the sight|Witnessing it had made you blush}.

"Why?" you rasp, shaking away the memory.

He glances back at the shed housing the heroes' ship.

"I'm good at fixing things, but I'm even better at fixating on them. My mind is always working, always looking for ways to make what could be, be." He gives you a sheepish smile. "I try to use this time to quiet it down. Focus on what is. Or better yet, focus on nothing at all, and just enjoy the view."

*fake_choice
    #"It's a good view."
    #"How self-aware of you."
    #"Does it work?"
        "Sometimes," he answers.

        He squints at the horizon, then returns his gaze to you.

"How about you? Is there anything you enjoy doing, aside from warning mortals off hubris?" he asks casually.

But he's watching you closely.

@{(hobby) "I weave."|"I train."|"I play the aulos."|"I like to play games."}

@{(hobby) He glances at your hands. "I see."|He nods. "Care to give me some tips?"|That seems to surprise him. "You must bring it with you next time."|That seems to surprise him. "What kind?"}

You chat away, feet dangling over the rippling sea, sky dimming over your head.

It dawns on you, after the sun is long gone and you finally part ways, how right Ares was.

[i]I know it is hard for beings such as ourselves to grasp the passage of time.[/i]

But tonight, you did. Not only did you watch it shift, but also felt it slip away from you.

And, after bidding Theron good night, for the first time in your eternal life, you wished you had more of it.
*goto home

*label morpheus1
*page_break

He's waist-deep by the time you land on one of the large rocks jutting out of the lake, next to his discarded chiton.

He has his back to you, wings wrapped around his shoulders like a shroud. If it weren't for the glow of his long, white hair and the sheen of his pearly skin, it would be impossible to tell where his wings end and the water begins.

You have no doubt he knows you're here.

Still, he doesn't turn around.

*page_break

The lake gleams like polished onyx, and mist hovers above it like steam. You haven't spent much time this close to the Erebus mountains. This close to where Morpheus dwells. The sky is darker here, thicker. Perhaps that's why there aren't many souls floating in its midst.

"Don't you have an Olympian to bow and scrape before?"

The words slice through the mist curling around you both. His tone is more vicious than usual. Sharpened by something that, if you didn't know better, could pass for jealousy.

"What's that supposed to mean?"

He turns to face you then, revealing the well-defined panes of his torso, the honed arrow point of his hips. What's beneath them, however, remains hidden by the water.

"My eyes are up here, Princess."

*choice
    #Two can play at this game; I rip off my gown and get in the lake.
        *set demure %-5
        *set Morpheus %+10
        *set goinginlake true
        Cold water nips your thighs as you slide in and approach him. Slowly and leisurely, @{(demure < 50) so that he gets a good look|ignoring the shame warming your cheeks}.
        *gosub_scene subroutines lake
        *goto postlake
    #I hug the shore and put my game face on; he won't catch me looking again.
        *set stealth %+10
        *set Morpheus %+10
        *goto postlake
    #I play up my frustration; I know how much he enjoys believing he got under my skin.
        *set cunning %+10
        *set Morpheus %+10
        *goto postlake
    #I stare him down from the shore; his little games don't rattle me one bit.
        *set charm %-5
        *set Morpheus %-5
        *goto postlake
    #I lift my chin; I don't have neither the time nor the inclination for this game.
        *set ruthless %+10
        *set Morpheus %-10
        *goto postlake


*label postlake

"You flatter yourself. There isn't much to see," you tell him.
 
"We both know that's a lie."

You size each other up, two cats trying to make the other feel like a mouse. 

"What do you want?" He asks, long, beringed fingers tracing circles on the lake's glossy surface. 
*if thoughtof = 2
    "Other than to marvel at me, of course."
    *goto morpheus2
*else
    "If you've come to @{(race) gloat, don't. It's unseemly. Unless I'm the one doing it."|bow in acknowledgement of my superior strength and speed, please go ahead."|tear through me like you did those poor birds, please don't. I'm rather fond of my limbs. And so are you, by the looks of it."|tear through me like you did those poor birds, please don't. I'm rather fond of my limbs. And so are you, by the looks of it."|sing my praises as our little contest's indisputable victor, please don't. I'm far too humble for that. You can simply list them."|apologize for not taking our little contest seriously enough, I'm all ears."|praise me for being so good–and fast–at delivering dreams, please go ahead."|pretend you didn't lose last night, please go ahead. We both know who the real winner is" He pauses for a beat. "Me. The real winner is me."}
    *goto morpheus2

*label morpheus2

You push away your rising annoyance and weigh your next words carefully.

*choice
    #"It was brave of you to call out Olympus like that," I say sincerely.
        He shrugs. "I was merely pointing out the obvious. Things have gotten out of hand lately. For all their talk of balance, they don't seem all that keen to uphold it. In fact, Hermes appears set on the opposite."
        
        *if dutiful < 45
            *set peoplepleaser %+10
            *set underworldinfluence %+10
            *set Morpheus %+10
            "You're right."

            As wrong as it feels to agree with him, excusing Hermes's behavior would be far worse.

            Still, these are dangerous words you're exchanging, no matter how much you believe in them. 
            *goto morpheus3
        *else
            *set underworldinfluence %-10
            *set Morpheus %-5
            You glance up at the sky, half expecting a lightning bolt to part it on its way to strike Morpheus down for being so openly blasphemous.

            "Ah," he sighs, as if he can read your thoughts.
            
            His disappointment does nothing to lessen your fear.
            *goto morpheus3
    #"Tell me what's going on between you and Hermes," I say firmly.
        He regards you closely, as if pondering his response.
        *if leadership > 50
            *set maverickgoddess %+10
            *set underworldinfluence %+10
            *set Morpheus %+10
            You welcome the scrutiny, meeting his gaze with all the poise you can summon.

            It must be a considerable amount, because he decides to tell you.

            "For all Olympus's talk of balance, they don't seem all that keen to uphold it. In fact, Hermes appears set on the opposite. Not that he likes to hear it." He shrugs, as if he's discussing something of little consequence, as opposed to what sounds dangerously close to blasphemy.
            *goto morpheus3
        *else
            *set maverickgoddess %-10
            *set underworldinfluence %-10
            *set Morpheus %-10
            Your impatience flares up at the scrutiny.

            "Well?" You push.

            His eyes narrow. "Who says there's anything going on?"
            *goto morpheus3
    #"I was impressed by the way you handled yourself earlier," I say airily.
        *if charm > 45
            *set pantheonplayer %+10
            *set underworldinfluence %+10
            *set Morpheus %-10
            His grin widens.

            "I'm not surprised. I'm a very impressive god."

            "Just this once, I'm inclined to agree," you allow with a smile.

            That surprises him. For a moment, you think you catch the ghost of a blush creeping into his cheeks. He notices you noticing and smirks.
            *goto morpheus3
        *else
            *set pantheonplayer %-10
            *set underworldinfluence %-10
            *set Morpheus %-10
            "Who is flattering themselves now?" He snarls. "You're about as charming as an empusa, and just as hard on the eyes."

            It's your turn to smirk. "We both know that's a lie."
            *goto morpheus3

*label morpheus3
*page_break

A couple of souls pierce through the mist nearby. They dart towards the space between you and Morpheus, their reflections like tiny beams of moonlight on the lake.

You watch their dance in silence. Not exactly a truce, but something close to it.

"Sometimes, when I sink below the water's surface and darkness embraces me, I wonder if it feels as peaceful for them," Morpheus says softly. "After they drink from the Lethe, just before they…forget."

You smother a gasp. The same thought has crossed your mind many times over.

Which must mean he's mocking you.

*page_break Right?

Voices echo in the distance, startling the souls. They flit back into the mist as you @{(goinginlake) sink into the lake, letting the water come up all the way to your neck before|glance behind you and spot} two godlings emerge from the woods.

You have seen them before. At the occasional feast, and whenever they accompany their father to the acropolis on business.

*page_break Morpheus's Brothers

They look nothing like him, but they're the spitting image of Hypnos. Warm brown skin, soft hazel eyes, curls dark as midnight.

It strikes you then, how little Morpheus resembles him.

"Morpheus! Is it true you have the night off?" One of them shouts. The older, lankier one. Phantasos, you believe.

"Of course it is, Phan. He is the finest messenger in the Council, deserving of every reward," the younger one adds. Ikelos, if you're not mistaken. His words are labored and stilted, as though he has rehearsed them, but not for very long.

"You're so right, Iki," Phantasos intones, leading the way to the shore. "The finest messenger indeed. Hey, since he has been relieved of his duties–which he carries out so admirably–you don't suppose he'll be kind enough to take his beloved brothers to the Lacedaemon boxing?"

"I'm certain of it. His kindness knows no bounds," Ikelos replies.

*page_break

They are so focused on spurring each other on that they don't notice you until they reach the shore. Ikelos frowns, eyes darting between you and Morpheus. Phantasos, gawks at you, mouth wide.

"Well, I'm glad that's over. As much as I loathe thespians, they deserve better than your pitiful attempt at their craft," Morpheus says. 

His tone isn't as biting as usual, his gaze mischievous rather than cruel.

Ikelos snaps out of his stupor first. He bows, dragging a still bemused Phantasos down with him.

"It is an honor to meet you, goddess," he stammers. "Properly, I mean. Of course, we have seen you at the acropolis. Not that you would remember. That is to say, your parents throw a fine feast."

Morpheus rolls his eyes. "Don't flatter her, Iki. It will go straight to her head."

You ignore him, smiling at his brothers instead.

"Pay him no mind," you begin.

*fake_choice
    #“He is merely jealous of your good manners, since he doesn't possess any.”
    #"He was just saying how much he was looking forward to taking you to Lacedaemon."
    #"Though he isn't wrong; too much flattery will make you as unbearable as he is."

Ikelos chuckles. Morpheus groans. 

"He also mentioned he would buy you all the honey biscuits you like at the boxing," you add.

Both their faces light up at that. 

"Truly?" Phantasos gasps, barely able to contain his excitement.

Morpheus sighs dramatically. 

"I suppose I could eat."

*if goinginlake
    He narrows his eyes at you then saunters out of the lake, wings trailing him like a cape.

    He slips his chiton back on with far too much grace.

    "Alright boys, let us feast and watch mortals pommel each other for sport." 

    You wave them off, waiting until their excited voices are nothing but excited whispers before making for your gown.
    *goto home
*else
    You @{(flightstyle) spread your wings|summon your shadows|flex your toes} and lift a few feet into the air. "I best get going, then. Don't want to delay the fun."

    Morpheus's eyes follow you as you take to the sky. You feel them on you long after you leave the clearing behind.
    *goto home

*label ares1
*page_break

You sit at your desk and lay out a fresh scroll, picking at the cake while you wonder what to write. It's almost gone by the time you put quill to parchment. 

[i]Ares,[/i] you begin. 

[i]I gladly accept your invitation.[/i] 

Then you pause. Your penmanship is @{(dutiful > 50) immaculate thanks to attending lessons with the best tutors. You were a dutiful student, always eager to please them, and it shows on the page. But what you wish to convey is far more elusive|atrocious. Despite your tutors' best efforts, you took pleasure in never doing what they asked of you. Still, your wonky handwriting isn't the issue here. Not really. It's what it conveys. Or rather, what it doesn't convey}.

You stare at the greenery beyond your balcony. Ambrosia lingers on your tongue, warm and syrupy. Souls flit in and out of your chambers, their reflections silver beams on the tiled floor.

Inspiration strikes as you watch them.

You will write something….

*choice
    #Fun and flirty.
        Yes, something that will get his heart racing and you stuck in his thoughts.

        [i]I look forward to enjoying each other's company without any distractions[/i], you add. 
        *if demure < 45
            *set Ares %+10
            *set maverickgoddess %+10
            *set flirtyscroll true
            [i]I must possess even less willpower than you, for I have already devoured your kind gift. Then again, why would I deny myself the pleasure of sampling something delicious? I have never been good at restraint, though I'm not opposed to it in the right circumstances.[/i]

            You imagine the blush that will color his dimpled cheeks when he reads that and grin.
            *goto ares2
        *else
            *set maverickgoddess %-5
            The words alone are enough to make you blush. 
            
            The images they conjure are worse, however, and you find yourself reaching for a cup of nectar, feeling suddenly thirsty.

            @{(background) When it comes to matters of the heart, you're far from inexperienced. Certainly well past these sort of awkward fumblings. But something about Ares makes you feel so…bashful. So green|It's been a while since you courted anyone, and it shows|This is uncharted territory for you, and it shows|You're out of practice, and it shows}. 
            
            Sighing, you crumple the parchment into a ball and chuck it on the floor.
            *goto ares3
    #Sweet and friendly.
        Yes, something that will warm his heart as much as his message warmed yours.

        *if charm > 40
            *set Ares %+10
            *set pantheonplayer %+10
            Smiling, you begin to write anew.

            [i]I look forward to revisiting the oak grove. @{(wentwithares) Our stroll the other day reminded me of|I should have taken you up on it the other day. I have been reminiscing about} the time we dressed up as drakons in an attempt to befriend them. You almost lost a finger![/i]

            [i]I also must thank you for the kind gift. @{(distantares) I'm afraid I've already devoured it, but I will make sure to taunt Zagreus about it regardless. He'll be devastated I didn't share|I, too, have an astounding lack of willpower, for it has been promptly devoured and left me craving more}.[/i]
            *goto ares2
        *else
            *set pantheonplayer %-5
            You begin to write anew. Or attempt to. But, try as you might, the words elude you. 
            
            Perhaps you have worn your armor too long. Perhaps it has melded to your skin. You're not used to being charming, let alone kind. Beating brows, ruffling feathers, throwing punches. That you can do with your eyes closed. This, you're not sure you can do at all. 
        
            Sighing, you crumple the parchment into a ball and toss it on the floor.
            *goto ares3
    #Courteous and pleasant.
        This is no state visit, that much is clear. But it would pay to approach it tactfully regardless.

        *if diplomacy > 40
            *set Ares %+10
            *set olympusinfluence %+10
            [i]I look forward to conversing one-to-one,"[/i] you write. 

            [i]I also wish to thank you for the kind gift. @{(distantares) I'm afraid there will be no taunting, for it is almost gone. A testament to your skill|Give my regards to Maia, it seems I owe her too}.[/i]
            *goto ares2
        *else
            *set olympusinfluence %-5
            You wreck your brain, searching for the right words. But everything you write comes across cold and insincere.

            It's tricky, navigating this type of meeting. Olympus is still Olympus, and your presence there is political whether Ares wishes it to be or not. 

            Sighing, you stare at the blank page, riddled with doubt.
            *goto ares3

*label ares2

You sign off and seal the scroll. One of your Epiali will bring it to Iris when they return from Hellas.

Satisfied, you join the fun raging outside. You eat, drink, and dance. By the time you stumble into your chambers and sink into the bed you seldom use for sleep, you're full of meat and merriment.

Lying there surrounded by silk, it's easy to picture Ares in Olympus's vast kitchens, whisking cake batter while Maia watches over him, sneaking a taste whenever she looks away. 

It's easier still, to smile at the thought.
*goto main19

*label ares3

In the end, you settle for a simple [i]I look forward to it[/i] and promptly thank him for the gift before signing off.

The new moon will be upon you soon enough, and you're certain you could have wasted an eternity agonizing over the best thing to write–and still come up short.

You roll up and seal the scroll with a resigned groan. One of your Epiali will bring it to Iris once they return from Hellas.

Sighing, you join the fun raging outside. You eat, drink, and dance. By the time you stumble into your chambers and sink into the bed you seldom use for sleep, you're full of meat and merriment.

Though not enough to feel a pinch of shame whenever you glance at the scroll.

*label main19
*page_break Rest Up

The three nightmare runs that follow are a whirl. Hermes's scrolls don't mention Theron, but they do send you to the farthest corners of the mortal realm and on rather complex assignments. Almost as if he's trying to keep you away from the Lord of Leukas on purpose.

@{(thoughtof) An odd move|An odd move|Not that it's working. At least not in the Halfrealm}.

Though it's also possible he simply hasn't had the chance to broach the subject with Zeus yet. Immortality is the enemy of urgency; when you live forever, you have forever.

Either way, you don't have the time to dwell on his motives. Or to do anything other than weave terrible nightmares and direct your Epiali to do the same.

The night of the new moon is another busy one. You're sent to a southern Queen who poisoned her unfaithful husband. Apparently, Zeus is unhappy with her lack of remorse. 

Sets a bad example. Or gives other wives ideas.

*page_break

You find her in the Halfrealm's currents, dreaming of pigeons. Hundreds of them, crammed into cages. They flap their wings and press their beaks through the bars, desperate and afraid. Their coos make the Halfrealm's waves ripple as they wildly call out to her, begging to be freed.

"Hush, now," the Queen soothes them. "Be patient. I'll let you out, in time."

Slowly, carefully, she's unlatching the doors to the cages and setting the pigeons inside loose. Whenever a batch is released, she watches them fly away before promptly resuming her task.

As far as dreams go, it isn't the strangest one you've encountered by far. But the woman before you had watched her husband choke on his wine not two nights ago. You had glimpsed his death in a few of the servants' nightmares. Similar enough to know what is true and what is fear.

The Queen had continued eating her dinner while her husband collapsed, clutching his throat, grasping for air. Unfazed by the man she professed to love, the father of her children, the protector of her people, dying a painful and slow death before her.

What do you do?

*choice
    #Do as Zeus wishes; I weave a nightmare that makes her confront the moment head-on.
        *set queennightmare 1
        *if leadership > 60
            *set succeeded true
            *set olympusinfluence %+15
            *set worship %+10
            *goto queen
        *else
            *set olympusinfluence %-15
            *set worship %-10
            *goto queen
    #Do as Zeus wishes; I trick her into believing this very dreamscape is a nightmare.
        *set queennightmare 2
        *if cunning > 60
            *set olympusinfluence %+10
            *set maverickgoddess %+10
            *set succeeded true
            *goto queen
        *else
            *set olympusinfluence %-10
            *set maverickgoddess %-10
            *goto queen
    #Spare her the nightmare. If I were in her shoes, I might poison my unfaithful husband too.
        *set queennightmare 3
        Besides, you doubt a woman who speaks so sweetly to caged birds, who sets them free with meticulous determination, who watches them fly away with longing in her eyes, just poisons her husband out of the blue.

        Whatever he had done, it must've been bad to elicit such a reaction, or lack there of, from her.

        *if ruthless > 60
            *set maverickgoddess %+20
            *set succeeded true
            You will not make her relive it tonight, Zeus and his nightmare quota be damned.
            *goto postqueen
        *else
            *set maverickgoddess %-20
            *goto queen2
    #Spare her the nightmare. The pigeons make me suspect there's more to her story.
        *set queennightmare 4
        The sweetness in her voice when she soothes the birds, the determined set of her jaw as she sets them free, the pain in her eyes when she watches them take to the faded sky.

        This woman knows what it's like, to be kept in a cage.

        *if dutiful < 40
            *set peoplepleaser %+10
            *set olympusinfluence %-5
            *set succeeded true
            You will not build her a new one tonight, Zeus and his worship quota be damned.
            *goto postqueen
        *else
            *set peoplepleaser %-10
            *set olympusinfluence %-15
            *goto queen2

*label queen

Perhaps her husband had kept her in a cage similar to the ones she's so intent on unlocking, while he himself flew free. 

Or perhaps she feels moved by the suffering of animals, but not that of men. Either way, she ought to know Zeus is unhappy with her lack of remorse. She ought to be afraid. 

*label queen2

@{(succeeded) You will the Halfrealm's currents to change|Alas, despite your best efforts to make a quick exit, your presence makes her fears stir. They infiltrate dreamscape, ignoring your attempts at shoving them back into the depths}.

*if (queennightmare = 2) and (succeeded = false)
    Alas, they refuse. 

    Weird.

    You shake your head, roll your shoulders. Try again. But, no matter how many times you try, you can't seem to focus long enough to will anything but your own frustrations to the dream's surface.
    *goto queen4
*elseif queennightmare > 1
    The cages rattle as the birds fling themselves at the doors. Their coos turn to screeches, their feathers fill the air.The Queen's attempts to sooth them grow louder, but the birds' terrible bellows drown them out. She pushes to free them faster, almost tripping over herself, hands shaking.

    Then the gray waves around you close in, shifting into bars, turning the dreamscape itself into its own cage. 

    "No, no, no, no," she pleads.

    *if succeeded
        But you keep weaving the nightmare, keep narrowing her cage.
        *goto queen3
    *else
        Each time the word is uttered, @{(queennightmare > 4) guilt bury itself further into your conscience|you're reminded of your clumsy incompetence}. 

        You can still hear it even after you leave the nightmare behind, even when your Epiali rush to your side, sensing your distress.
        *goto postqueen
*else
    At once the cages disappear, replaced by a long table with two chairs on either end. The Queen sits in one, her husband on the other. Servants watch as he tucks into the feast laid before him with famished glee, while she takes in her new surroundings with suspicion, first, then @{(succeeded) fear|indifference}.

    *if succeeded
        fear. 

        When her husband begins to choke, grasping at the tablecloth, pulling it and everything on top onto the floor, the sound makes her jump. She rushes to his side, horrified at the sight of his reddening face, his wide, pleading eyes. 

        "What have I done?" she cries. "No, no, no no."
        *goto queen3
    *else
        And it remains that way, even after her husband begins to choke. No matter how many details you change, or add, or remove.  
        *goto queen4 

*label queen3

Only when you hear her utter, "No, please, Zeus, no" do you stop, allowing the @{(queennightmare > 1) bars to disappear, the pigeons to calm|feasting table to disappear, taking her husband's with him}.

For you know she will ask for the gods' mercy in the morning.

And, thanks to you, they will grant it.
*goto postqueen

*label queen4

The more you persevere, the least sure of yourself you become. Until you have no choice but to give up, to let her hubris go unpunished, and Zeus's orders go unfullfiled.

*label postqueen
*page_break

Dawn has come and gone by the time you finish up and head north, @{(succeeded) satisfied with your work for the night|still ashamed about your performance}.

*page_break Meet Ares

This isn't an official visit, so there's no need to use the official gate. 

The sun beats down on your back and the landscape changes beneath you as you fly north, towards the mountain range teetering on the edge of the west coast. There's another gate carved into the highest, sharpest peak.

The Cloud Gate.

The pillars are both made of ivory, but the abyss they frame is white and tufty, and a lightning bolt, not a three-headed dog, is carved into the keystone.

You @{(hair) run your fingers through your long hair|bunch up your tight curls with your fingers|adjust your braids|adjust your headscarf} and smooth your @{(style) chitoniskos|chiton|peplos}. 

You picked this one so Ares will think you look

*fake_choice
    #Beautiful. Hence the tailored fit and delicate pins.
        *set charm %+10
    #Formidable. Hence the belt and adamant pins.
        *set charm %-5
    #Regal. Hence the intricate embroidery and gold pins.
        *set leadership %+10

You step through the white smoke and emerge on a wooded hill gilded with ambrosia.

Even your divine eyes struggle against the brightness. Most of it radiates from Zeus's golden palace, glinting above the treeline in the distance like a would-be sun.

You make your way towards the grove on foot, lest you announce your presence to the whole pantheon.

The wood here is different than in the Underworld. Less misty, for one. Tidier too. The leaves are an impossible shade of green to match the sky's impossible shade of blue. There is more space between the trees, less leaves and branches and roots scattered on the ground.

The creatures you spot are different as well. There are the bees, of course. Eagles, boars, and a chimera, hiding among the bushes. Its goat head watches you walk by, but its lion one is locked on a dove minding its business nearby. 

Judging by the hunger in the lion's amber eyes, it won't be minding its business for much longer.

Eventually, the trees start thinning out and the forest floor gives way to grass. You can feel its softness through the sole of your sandals. It's like stepping on a cushion.

*page_break Find Ares

*if wentwithares = false
    The oak grove comes into view up ahead.

    Ares sent another @{(leaningtowards) lovely scroll|scroll|scroll} suggesting you meet him by the tree you used to climb to watch drakon eggs hatch. You remember its location. Deep in the grove, by a noisy stream.

    You hear it before you see it. A silver ribbon winding through the green. Ares is crouching by a huge oak bending over its surface, toying with the hem of his chitoniskos.

    He isn't wearing his leather cuirass, but he still looks very much the warrior. Tall and broad and fierce even when he's hunched over something you can't quite see.

    "Ares," you call out.

    His head jerks up. He brings a finger to his lips and points at a hollow in the oak's trunk.
    *gosub_scene subroutines predrakon
    *goto drakoneggs3
*else
    It isn't hard. 

    He's in the grove. He isn't wearing his leather cuirass, but he still looks very much the warrior. Tall and broad and fierce even hunched over the tree hollow full of drakon eggs. 

    @{(stealth > 45) A gasp slips from his lips when you crouch by his side|Despite trying to be quiet, he hears you approach}.

    @{(stealth > 45) "Sorry," you mouth. You didn't mean to sneak up on him|"Hi," he mouths with a smile. So much for stealth}.

    @{(stealth > 45) He waves you off|You crouch by his side}.

    "I think it's happening," he whispers, excitement pulsing through him. 

    His eyes are wide, his dimples firmly in place. 
    *goto drakoneggs3

*label drakoneggs3
*page_break

A whimpering sound draws your gaze to the hollow, where the eggs have begun to quiver. If the young feel threatened, they won't hatch. You've seen it happen before. An egg about to pop, gone still as stone. They can stay like that for centuries, frozen just before birth, waiting until the world is safe enough to come into it.

One of the eggs gives a jerks. Then its white surface splinters and thick, clear liquid seeps out.

A tiny, baby drakon bursts through the cracks.

What do you do?

*choice
    #I cozy up to Ares while marveling at the drakon.
        *set aresfriends true
        You brush your arm against his.
        *if demure < 35
            *set Ares %+10
            He moves it immediately, adjusting it so you can get closer. 
            
            You lean against the swathe of his sculpted chest, resting your head in the crook of his arm. He's all brawn and hard edges, but it doesn't feel uncomfortable to press into them.

            Far from it, in fact.
            *goto main20
        *else
            *set Ares %+10
            A blush spreads across his cheeks. You're certain it matches your own.

            But you're both too shy to do anything more than steal coy glances at each other.
            *goto main20
    #I imitate the sound of a drakon hen to trick the others.
        You clear your throat and begin squawking.
        
        Ares stares at you as though you've gone mad, but you soldier on, trying to sound as close to a drakon hen as possible.
        *if cunning > 45
            *set Ares %+10
            *set daemonhandling %+15
            *set coaxedeggs true
            And succeeding.

            The remaining eggs begin to jerk back and forth in tune with your clacking and clucking.

            "Unbelievable," he chuckles, shaking his head.
            *achieve becomethedrakon
            *goto main20
        *else
            *set daemonhandling %-10
            And failing miserably.

            No matter how much you clack and cluck, the remaining eggs do nothing more than gently quiver.
            *goto main20
    #I reach out to pet the drakon.
        You can't help it, she's too cute. 
        
        "Careful."
        
        You bring your finger to her scales, ignoring Ares's whispered warning. She stares up at you, her reptilian eyes curious.

        *if daemonhandling > 45
            *set daemonhandling %+15
            *set maverickgoddess %+10
            *set Ares %-5
            As soon as you rub under her chin, she closes them. Soon, she's purring.

            "Unbelievable," Ares chuckles as the remaining eggs begin to lurch back and forth.
            *achieve drakonwhisperer
            *goto main20
        *else
            *set maverickgoddess %-10
            *set daemonhandling %-10
            *set Ares %-5
            *set bitbydrakon true
            They narrow as you go to rub her chin, and the egg tooth she used to carve her way into the world sinks into your skin.

            You snatch your hand back. "Ouch!"
            
            Ichor sprays the grass gold. You hold your finger up, inspecting the wound. The torn skin may already be stitching itself back together, but that doesn't mean it wasn't painful.

            You glare at the drakon, but she merely blinks, much to Ares's amusement.
            *goto main20

*label main20
*page_break

A second hatchling breaks through its egg, slashed pupils wide, silver scales glinting. 

The third takes a little longer. @{(bitbydrakon) You watch gingerly, keeping your hands to yourself|You scuttle closer, fearing you might have scared it off}. Then the shell finally cracks, and the last hatchling joins her siblings.

Relief floods you as they chirp at each other, bumping snouts and twisting their tales together.

*if coaxedeggs
    "Here," Ares says, handing you a container full of worms.

    You tip it onto the nest. "Dinner is served."
    
    They perk up at the sound of your voice, as though they recognise it. Looking at them like that, all tiny and adorable, it's hard to imagine they'll grow into such huge, fearsome creatures.
    
    "Go on," you tell them.

    Only then do they dive for the worms.
    *goto postdrakon
*else
    @{(bitbydrakon) As tiny and adorable as they are now, the memory of that tooth–a baby tooth!–nicking your palm is too recent not to think of the huge, fearsome creatures they'll become|Looking at them like that, all tiny and adorable, it's hard to imagine they'll grow into such huge, fearsome creatures}.

    Ares grabs a container full of worms and tips it into the nest.
    *goto postdrakon

*label postdrakon

"Aren't you guys precious? Oh, yes, yes you are," the god of war coos. He can barely contain his delight. 

In fact, you doubt those dimples of his will ever leave his cheeks now.

*page_break

After the hatchlings are done eating and sleep tugs at their eyelids, Ares gathers up the egg shells and places them by the stream. 

"To confuse predators while they rest," he explains, dunking his hands in the silvered water.

@{(bitbydrakon) "Behave," you whisper at the hatchlings before joining him|You give the hatchlings a final pet and join him}. 

The stream is known for its healing properties, and @{(bitbydrakon) the tenderness where the hatchling bit you disappears as soon as you plunge your fingers into it|though there's nothing for it to heal or cleanse, you feel its restorative power like a caress}.

*if (wentwithares = true) and (thoughtof = 1)
    Ares wears the same satisfied expression he did at the front, after the warriors were fed and abed.

    "C'mon," he says, heading towards the treeline and gesturing for you to follow.
    *goto postdrakon2
*elseif (wentwithares = true) and (thoughtof > 1)
    @{(bitbydrakon) Despite the attack, you're|You're} glad you didn't miss it.

    Glad Ares thought of you, @{(leaningtowards) the same way you've been thinking of him, ever since receiving his letter|even if you haven't thought of him so much|even if you haven't thought of him so much}.

    "C'mon," he says, heading towards the treeline and gesturing for you to follow.
    *goto postdrakon2
*elseif (wentwithares = false) and (thoughtof = 1)
    First the warriors, now the hatchlings. 

    Is there anyone, or anything, Ares won't take care of?
    *goto postdrakon1
*else
    *if (leaningtowards = 2)
        @{(lefttheron) What would a mortal do, you wonder, to have access to it?|Its touch makes you think of Theron, water dripping from his curls and down his forearms after he washed the day's work off at the shipyard}.
        *goto postdrakon1
    *elseif leaningtowards = 3
        Its touch makes you think of Morpheus, carved into the lake like a perfect marble statue, shrouded in wings and mist.
        *goto postdrakon1
    *else
        And are glad Ares chose to share this with @{(bitbydrakon) you, despite the attack|you}.
        *goto postdrakon1

*label postdrakon1
*page_break

"How long have you been watching over them?" you ask Ares.

"A few weeks. I was hoping they would hatch today."

"Is that why you invited me?"

He glances at you, then back at the water. "Partly." 

He finishes washing his hands and heads towards the treeline, gesturing for you to follow. "C'mon."

*label postdrakon2
*page_break

You let him lead you further into the grove, until you reach a small glade where the stream feeds into a sparkling pond. 

A blanket has been laid out on the grass. There's a pitcher of nectar and a wicker basket filled to the brim with food. Cheeses, fruits, nuts and a fresh batch of perfectly golden ambrosia cakes.

"I didn't know what you'd fancy, so I brought a bit of everything," he says.

You kick off your sandals and perch on the blanket. It's an idyllic spot, sheltered from the palace but still bathed in its glow.

Ares settles opposite you, close enough that, if he splayed his fingers, they would brush against yours.

*fake_choice
    #I find myself wishing they would.
        *set Ares %+10
        *set aresfriends true
        You study him closely.

        He makes for a pretty enthralling view. One you intend to make the most of while you eat.
    #I'm not sure how I would feel if they did.
        *set Ares %-5
        @{(leaningtowards) Writing letters is one thing, actually being with him like this is quite another|Theron's rugged hands sneak into your thoughts again, surprising a smile out of you|Morpheus's cruel smirk sneaks into your thoughts. Fates, he is [i]so[/i] vexing.}

        You reach for the food, hoping it will help shake @{(leaningtowards) the uncertainty|the memory|your annoyance}
    #I'm feeling more hungry than handsy.
        *set Ares %-10

Before you can tuck in, however, Ares clears his throat.

"${name}. There's something I wish to discuss with you. Something important." He rakes a hand through his hair. "I'm sorry for the way Aphrodite accosted you, after I left the feast. She shouldn't have done that, let alone on my behalf." 

He trails off, staring at the pond before adding, "I'm sure you've heard the rumors about us. I don't wish to excuse what happened between us, but I'd like to explain myself."

*page_break Hear Him Out

@{(leaningtowards) If you are to have a future together, you deserve to|It doesn't hurt to|It doesn't hurt to} @{(indifferentaprhodite) know, you suppose|know}. 

"@{(thoughtof) I'm sure you've gathered as much already, but even though I'm a god of war,|I may be a god of war, but|I may be a god of war, but} I despise waging it. I don't have a head for strategy, nor a cunning tongue. My father and siblings think of war as a game, and of me as a clumsy fist smashing through the board."

@{(parentsrel) Hearing the sorrow in his voice when he speaks of his family makes you grateful for your own|You nod in understanding. You know the pain that comes from being misunderstood by your family well|It's hardly surprising to hear him say so. Families are like labyrinths. Complex to navigate and full of dark secrets}. 

"For a long time, I did everything I could to prove myself to them. To justify why I only spill blood as a last resort. But all they see is a coward. A waste of brute strength." 

He pauses, picking at the grass. @{(thoughtof) You think of him at the border, making stew and joking around with the warriors|Feeble-minded and helpless, Zagreus's harpist had called him. But those were Athena's words. Words he's used to, by the sounds of it|Feeble-minded and helpless, Zagreus's harpist had called him. But those were Athena's words. Words, he's used to, by the sounds of it}.

"Then Aphrodite came along. She too had been wronged by my father and the pantheon. Married off to Hephaestus as part of some deal she had no part or say in."

@{(marriage) A marriage brokered out of greed|A marriage that increased the power, status and wealth of others rather than her own|Married off to a god she didn't love|Married off against her will}. You can't think of a worse fate.

"We were young and reckless, yes, but above all else, we were lonely and hurting," Ares adds. "So we found solace in each other. A semblance of it, anyway."

*fake_choice
    #"Do you love her?"
    #"Do you regret it?"
    #"Do you miss this [i]solace[/i]?"

"I don't. What we had was a distraction from our turmoil. And, ultimately, it only added to it. We both deserve better than that. I suppose we had to go through it to realize it." He gently tugs at the grass. "I suspect your interaction has less to do with our relationship, or lack thereof, and more to do with worship."

That hadn't occured to you. But she [i]is[/i] the goddess of love, beauty and desire. Meant to be able to floor mortals and gods alike with a single glance. 

You suppose it doesn't look great for her if it gets out that her long rumored-lover is being floored by someone else.

Whether it's the truth or not.

*page_break

"There you have it," Ares sighs. "My sordid past in depressing detail."

He seems relieved to have addressed it. Not as joyful as he was when you first arrived, after the drakon eggs hatched, but lighter.

"What about you, huh?" he probes. "Any tales of heartbreak and woe you'd like to share to even the scales a little? You must have a long line of suitors willing to do anything for your hand in marriage."

*if marriage != 4
    @{(marriage) None that would ensure the realms are united|None powerful enough to grant you the status you seek|It wouldn't matter either way, since you don't love them|na}

    Still, it gets you thinking. If you were to be asked for your hand in marriage, how would you prefer it be done?
    
    *fake_choice
        #Intimately, just me and my intended.
            *set proposal 1
            *set demure %+10
        #With my loved ones present to witness it.
            *set proposal 2
            *set parents %+10
        #I'd prefer to propose to my intended myself.
            *set proposal 3
            *set leadership %+10

    Perhaps @{(proposal < 3) your intended would craft a ring for you|you would craft a ring for your intended}, the way some mortals do, and present it so that @{(proposal < 3) you|he} might wear it on the finger they believe is connected to the heart.
    *goto postproposal
*else
    Even if there were, you would never entertain them. Not on the marriage part, anyway.
    *goto postproposal

*label postproposal

@{(marriage < 4) You|Still, you} think of @{(leaningtowards) his letter, and how your heart pounded as you rushed home to respond to it|Theron, watching the sun disappear behind the horizon|Morpheus, taunting you in the lake, by the gate, in Hellas's sky}.

*if background = 1
    "I'm usually the one breaking the hearts and causing the woe," you admit, clearing your throat.

    Ares's grin widens. "That doesn't surprise me."
    *goto main21
*elseif (background = 2) or (background = 4)
    "I loved someone once, long ago. It didn't end well," you admit, clearing your throat.

    You expect him to pry. Most deities do. 
    
    "That doesn't mean it didn't leave a scar, and I've fought alongside enough mortal warriors to know that scars feel tender from time to time, no matter how old," Ares offers instead.
    *goto main21
*else
    "I've never actually been in love," you admit, clearing your throat.

    You expect him to ridicule you. You're an immortal goddess. To not have experienced such a thing in your long lifespan is, and has been, an easy target for mockery.

    "It's something you can neither force nor rush, I think," Ares offers, somehow managing to be gentle without being patronizing.
    *goto main21

*label main21

*if wentwithares = false
    *gosub_scene subroutines marriagetalk
    *goto postmarriagechat
*elseif (wentwithares = true) and (aresmarriagetalk = false)
    *gosub_scene subroutines marriagetalk
    *goto postmarriagechat
*else 
    *goto postmarriagechat1

*label postmarriagechat

"Still, I've witnessed how miserable and bitter unwanted unions can make those pushed into them," he adds picking at the grapes. "I'd rather avoid that."

*page_break 

"I'll drink to that," you say, pouring two cups of nectar and raising yours.

He grabs his and follows suit.
*goto main22

*label postmarriagechat1
*page_break

He hands you a cup of nectar. "Let us have a toast." 

You raise your cup. He does the same. 

*label main22

"To long overdue catch-ups between old friends," he says cheerfully, bringing it to his lips.

And it dawns on you, when he says it.

*choice
    #I want us to be more than friends.
        *set Ares %+10
        The certainty makes everything but him fade.
        *goto interestedares
    #I could see us becoming more than friends.
        *set Ares %+10
        *set curiousaboutares true
        *goto interestedares
    #I don't ever see us becoming more than friends.
        *set Ares %-5
        *set aresoutcome 1
        *set justfriendsares true
        He's so easy to be around.
        
        A ray of sunshine, piercing through the shadows of your world. Making it brighter, but never setting it alight. 
        *goto notinterestedares
    *if (leaningtowards > 1) and (aresfriends = false)
        #I think we're too ill-suited to be friends.
            *set Ares %-20
            *set aresoutcome 2
            @{(ruthless > 45) He's too soft, too|He's sweet in a way deities seldom are, yes. But he's also rather} boring.

            @{(ruthless > 45) Thinking so may be cruel, but it's also|You're not proud of thinking so. It's cruel, even if it's} the truth.
            *goto notinterestedares

*label interestedares

He's so easy to be around. And sweet in a way deities seldom are.

Handsome, too.

Blissfully unaware of your @{(curiousaboutares) casual|shameless} leering, he plucks an ambrosia cake from the batch and takes a bite.

"Did you make those too?" you ask, distracted by the trail of syrup glinting below his bottom lip

"I did. Maia says they're my best ones yet. Perhaps you'd like to judge?" He nods at the cakes, but frowns when he catches you looking at his mouth. "Oh, Fates. I've got ambrosia all over myself, haven't I?"

He rubs at his jawline, but manages to miss the stain entirely.

*fake_choice
    #"Allow me," I offer.
        *set offeredhelp true
    #"Need a hand?" I tease.
        *set offeredhelp true
    #"You made it worse," I point out.
    #I merely chuckle at him.
    
@{(offeredhelp) "Please," he groans|"Do you mind?" he pleads, scooting closer to you}.

@{(offeredhelp) You scoot closer to him and cup|"I guess I could offer a hand," you agree, cupping} his face.

It takes a few swipes of your thumb across his chin to get the ambrosia off.

Only when it's done, do you realize how close he is.

His throat bobs, and you feel it against the palms of your hands, still resting on his cheeks.

You drag your gaze from his lips back to his eyes.

Mere friends–old or otherwise–don't look at each other the way he's looking at you.

Like the lion eyeing the dove. 

Like you're something he'd like to taste.

Before you know it….

*choice
    #My lips are on his.
        You kiss him softly, at first. Savoring it.
        *gosub_scene subroutines areskiss
        *goto areskiss2
    #His lips are on mine.
        He kisses you softly, at first. Like he wants to savor it.

        You savor it too.
        *gosub_scene subroutines areskiss
        *goto areskiss2
    #Our lips meet.
        Softly, at first. Like you both want to savor it.
        *gosub_scene subroutines areskiss
        *goto areskiss2
    *if curiousaboutares
        #I pull away from him.
            *set Ares %-5
            *set aresoutcome 3
            Yes, you can see the pair of you becoming more than friends. 

            That doesn't mean you have to this instant.
            *goto pulledaway

*label pulledaway
*page_break

You sit back, wiping your thumb on the blanket. 

Ares clears his throat. The shade of his cheeks matches his tunic, and his eyes dart away from yours.

"Where were we?" you wonder, @{(demure > 45) ignoring the warmth spreading across your own face|enjoying how bewildered he looks}.

"I belive you were about to judge my baking skills," he reminds you, voice hoarse.

You smile at him and reach for a cake.

"A task I'll take very seriously indeed." 

*choice
    #Continue to the next chapter.
        *finish Chapter 6
    *if (not(choice_randomtest)) #Restore to the previous checkpoint.
        *restore_checkpoint

*label areskiss2

They remain there when he pulls away enough to rest his forehead against yours.

"Whatever you want from me, you can have it," he murmurs.

He says so as gently as he's holding you, but you can feel the desire burning in his voice, and in the hardness pressing against your hip.

What do you want from him?

*choice
    #Everything. I push him back onto the blanket, eager to take it.
        *set aresoutcome 4
        *set sexwithares true
        *set Ares %+15
        *set ontopares true
        "In that case," you say, straddling his hips.

        Your gown rides up your thighs and he reahes up to touch them.

        "Fates," he rasps when the straps slide down your shoulders.

        His fingers sear your @{(flightstyle) hips, and your wings spring wide|hips|hips}. But you don't want to burn too much too soon, so you pin his wrists to either side of his head and grin.

        "Can I have this?" You taunt, grinding against his cock, over his tunic.

        His breath snags, his fists clench. But he nods, gazing up at you through lidded eyes. 

        "And this?" 
                
        You press your lips to his neck, nudging the hollow of his throat with your teeth.

        "Yes," he whispers as you flick your tongue over the soft spot behind his ear. "Fates, yes."

        Your grin widens. You pull back so you can see his face while your hips….

        *fake_choice
            #Keep a leisurely pace; I want to drive him crazy.
                *set demure %-5
                You take your time with each undulation, gently stoking the heat between your thighs.

                It's driving Ares crazy alright. He's making strangled little noises and his eyes are squeezed shut, as though he can't take the slow, agonizing friction and look at you at the same time.
                        
                It almost sets you alight, to see him like this. So undone by the subtle cadence of your hips.

                You kiss him again, matching your tongue to your hips' movements. Until the shape of his lips is branded into yours. Until you're the one who can't take it anymore.
            #Pick up the pace; I want to bring us to the edge.
                *set fitness %+10
                You grind against him faster, fuelling the heat between your thighs and the fire in his eyes. They're fixed on you, spurring you on, stoking those flames. 

                Your speed builds and builds and builds. Until the world becomes nothing but friction and frenzy. His chiton is wet beneath you, his lips parted wide, and he's making these strangled little noises that almost set you alight.
                        
                You kiss him, moving your tongue in tune with your hips, and you know the edge is near. You're both hurtling towards it. 
                
                A comet, careening and ablaze.
            #Stop moving altogether; I want to toy with him a little.
                *set ruthless %+10
                You go still. His cock presses between your thighs, and all you want to do is grind against it. 

                But you don't. Instead, you watch the heat in his eyes flare.

                "Perhaps I'll take my time with you," you say, nipping his chin.

                You move onto the nook where his neck meets his shoulder, then the dip beneath his clavicle. Your hips slide an inch, and he makes this strangled little noise. It almost sets you alight, to see him like this. So undone by the tiniest bit of friction, the slightest tease of your tongue.

                His lips part, as though he might complain. Or plead. Or both.

        "I'll have all of you now," you breathe.
                
        He moans, and you can't tell if it's out of relief or desperation.

        It doesn't matter. Nothing but your need for him matters. You let go of his wrists and rip the clips holding his chitoniskos together. He wrests it from under you and tosses it on the grass before he helps you shuck off your gown.

        You pause, taking a moment to appreciate his strong, powerful body, and how obscenely good it feels against yours.

        Then you're bracing your hands on his sculpted chest
        *if background = 3
            *set virgin false
            and are about to lower onto him. But a flicker of hesitation stops you.
            *goto checkinares
        *else
            and lowering onto him. There's another moan, but you can't be sure whose lips it tore from.
            *goto aressex
    #Everything. I lay back on the blanket, offering myself up to him.
        *set aresoutcome 4
        *set sexwithares true
        *set Ares %+15
        "Whatever you want from [i]me[/i], I want you to take it," you tell him, spreading your legs @{(flightstyle) slightly, wings spread to either side of you|slightly|slightly}.
                
        His breath snags. Then his mouth is tracing the hollow of your throat, the nook where your neck meets your shoulder, the soft spot behind your ear.

        "I'll take this," he whispers, removing one of the pins holding your gown together and kissing the newly exposed dip beneath your clavicle.
        
        "And this." He removes the other pin, bestows another kiss.

        "And this." Slowly, deliberately, he pulls the gown down. His knuckles leave a trail of fire on your breasts, your ribs, your hips, before he tosses the gown on the grass.

        The fire in his eyes flares at the sight of your naked body.

        *fake_choice
            #"My turn," I say, reaching for his chitoniskos.
                *set aresnaked true
                *set leadership %+10
                You take as much time undressing him as he did you, pressing your lips to every inch of golden skin you unveil. 

                His strong, sculpted body isn't honed for war. It's honed for shuddering under your tongue's careful ministrations.

                Fates, he looks good when he shudders.
                        
                You climb on top of him. His cock is hard between your thighs, but you don't lower onto him yet. You just slide against it, watching him shudder anew. 

                "Anything else you'd like to take?" You tease.
            #"And what else?" I breathe, desperate to find out.
                *set demure %+10
                He reaches between your thighs, stoking the heat there with slow, teasing strokes that have you arching your back and moaning against his mouth.

                It takes everything in you not to cry out when he stops. He knows it too, smiling as he brings his fingers to his lips.

                When he speaks, his voice is hoarse, and his cock is hard against your hip. "I'll take this."

                He licks his fingers as though he just dipped them in ambrosia, and it almost sets you alight.
            #"Is that all?" I challenge him, re-tracing the journey his hands made with my own.
                *set dutiful %-5
                You reach between your thighs, stoking the heat there with slow, teasing strokes. Soon you're gasping and arching your back, and the hunger in his eyes only adds to your pleasure.

                His hand wraps around your wrist and he brings your fingers to his lips. 

                When he speaks, his voice is hoarse, and his cock is hard against your hip. "I'll take this.".
                        
                He licks your fingers as though they've just been dipped in ambrosia, and it almost sets you alight.

        @{(aresnaked) He smiles and flips you onto your back. "Oh, I have some ideas."|Then he's kissing you, and you're wresting the chitoniskos from his shoulders, as hungry for him as he is for you. You shudder at the weight of his strong, sculpted body, somehow not heavy despite his sheer size.}
            
        You brace your hands on his broad shoulders.
        *if background = 3
            *set virgin false
            He goes to ease into you, but something in your face makes him pause.    
            *goto checkinares
        *else
            When he finally eases into you, you both gasp, but you can't tell if it's out of relief or desperation or both.
            *goto aressex
    #Only his lips.
        *set aresoutcome 5
        *set Ares %+10
        "I'll have as many kisses as you can give," you say, lightly pressing your mouth to his.

        He smiles. @{(aresmarriagetalk) "Deal."|"I'll drink to that. Later, once I'm done."}

        He kisses you again.
        
        And, for now at least, it's enough.
        
        *choice
            #Continue to the next chapter.
                *finish Chapter 6
            *if (not(choice_randomtest)) #Restore to the previous checkpoint.
                *restore_checkpoint

*label checkinares
*page_break

You haven't done this before. Not this part, anyway.

Ares has gone still @{(ontopares) above|beneath} you. "${name}?" He sounds concerned. "We can stop. We don't have to…." 

"No." Stopping is the last thing you want to do.

His fingers brush your cheek. "You're certain?"

You nod and @{(ontopares) guide him into you|lower onto him}. There's pain but only a flash of it. Nothing a goddess can't handle. Especially one that is already aching. 

For him, for this.

*label aressex
*page_break

He grips your hips and you fall into a rhythm that feels both exquisite and excruciating.

His heartbeat is a war drum against your @{(ontopares) palms|chest}, his grunts kindling to your moans. @{(ontopares) You pull him up towards you and hook your legs around his waist, needing to feel him|You wrap your legs around his waist, needing to feel him} closer, deeper, faster.

There's nothing brutish or clumsy about the way @{(ontopares) he holds you. He guides your hips at the perfect angle so that each time you bear down on him, it feeds|he moves. He's like a dancer. Graceful, lithe and precise. Each perfectly angled thrust feeds} the fire engulfing your body, scorching away any sane thoughts still clinging to your mind.

You dig your nails into his shoulders as you come. Pleasure ripples through you, and it doesn't stop when he follows, gasping as he pushes into you.

*page_break

Afterwards, you lie on the blanket, clinging to each other as he runs is fingers through your @{(hair) hair|curls|hair|hair. You're not sure where your headscarf is. Probably discarded along with the rest of your garments}. 

The light seems even more golden now, the pond shinier, his smile sweeter.

You know you should clean up. Probably talk about the future, and @{(aresmarriagetalk) whether this complicates his suggestion or not|what the Fates may have in store}. At the very least think about it. 

But for now, you just want to

*choice 
    #Enjoy this moment without worrying about what's next.
        You nuzzle the crook of his arm then rest your head on his chest. He wraps his arm around your waist, his palm warm against your hip.

        How could you worry about the future, when the present is so full of bliss?
        
        *choice
            #Continue to the next chapter.
                *finish Chapter 6
            *if (not(choice_randomtest)) #Restore to the previous checkpoint.
                *restore_checkpoint
    #Get cleaned up and finish the beautiful spread.
        You feel his eyes on your back as you wade into the pond, careful not to startle the dragonflies.
        
        They scatter when Ares joins you a moment later, giggling like a lovestruck nymph.
           
        You don't know if the water is freezing or the heat clinging to your skin makes it feel that way.

        But you enjoy it all the same.
        
        *choice
            #Continue to the next chapter.
                *finish Chapter 6
            *if (not(choice_randomtest)) #Restore to the previous checkpoint.
                *restore_checkpoint
    #Stoke those flames some more. After all, gods don't need rest.
        You look up at him through your lashes, fingers drawing circles on this chest.

        They trace the hard lines of his abdomen, the shape of his hip bone. You feel him harden against your thigh and smile.

        Then he's kissing you again, and you doubt you could think about anything else, even if you wanted to.
        
        *choice
            #Continue to the next chapter.
                *finish Chapter 6
            *if (not(choice_randomtest)) #Restore to the previous checkpoint.
                *restore_checkpoint

*label notinterestedares

Of course, that doesn't mean @{(marriage) you shouldn't marry him. Especially if it's what's best for the people. Right?|you shouldn't marry him, especially if it furthers your position in the pantheon. Right?|you're free to marry who you please. At least not without consequences.|your parents will stop pestering you to marry him.}

You clench your fists. @{(marriage) Could you be tied to him for all eternity, if you didn't love him?|Could you be tied to him for all eternity, if you didn't love him?|So be it.|So be it.}

*if justfriendsares
    @{(marriage) The answer can wait;|The answer can wait;|Now that's over,|Now that's over,} you have an old friend to catch-up with.

    And a picnic to enjoy.

    *choice
        #Continue to the next chapter.
            *finish Chapter 6
        *if (not(choice_randomtest)) #Restore to the previous checkpoint.
            *restore_checkpoint
*else
    "Are you alright?" Ares asks.

    "I'm fine."

    It comes out far curter than you intended. His face wilts, eyes darting to his cup of nectar, the dragonflies by the pond, the oak trees in the distance. 
    
    Anywhere and at anything but you.

    Fates, this is going to be a long picnic.
    
    *choice
        #Continue to the next chapter.
            *finish Chapter 6
    *if (not(choice_randomtest)) #Restore to the previous checkpoint.
        *restore_checkpoint